CYBER.XPO.95/CYBER.XPO.95 (Arsenal Computer).ISO/popreq/amiga1/dcdd_20.lha/Do_FAAX.rexx

OS/2 REXX Batch file | 1993-09-06 | 9KB | 326 lines

/*
   Do_FAAX.rexx                   Version 1.9                     930906.0303

             (you can follow along on the ZZZ_FAAX_session_log file)
*/



address BAUD /* must have this here */
OPTIONS RESULTS

parse arg N_args

parse var N_args PW1 PW2 Xargs

/*
msg '************************'
msg 'Args = ' PW1 ' ' PW2 ' ' Xargs
msg '************************'
*/

timeout 30

auto = 'X'
waitlost = ' '

if exists('ram:AUTO')~=0 then
   auto = 'y'

call LOGON

if auto = 'y' then do
   if waitlost = 'n' then do
      call AUTO_NEW_FILE_LIST
   end
end

if auto = 'y' then do
   if waitlost = 'n' then do
      if exists('dh1:-dl/DL_FAAX')~=0 then do
         call AUTO_FILE_DL
         if waitlost = 'n' then do
/*
            address command 'rename dh1:-dl/DL_FAAX dh1:-dl/DL_FAAX_done'

 if anyone can tell me why the above line will not work, while the next
    two will, please let me know. I'm stumped!
*/
            address command 'copy dh1:-dl/DL_FAAX dh1:-dl/DL_FAAX_done'
            address command 'delete dh1:-dl/DL_FAAX'
         end
      end
   end
end

if auto = 'y' then do
   if waitlost = 'n' then do
      call LOGOFF
   end
end

if waitlost ~= 'n' then do
   if exists('RAM:continue')~=0 then do
      address command 'delete RAM:continue'
   end
end

return


/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
 *                                                             *
 *                   Functions / Subroutines                   *
 *                                                             *
 * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */

LOGON:
address BAUD /* must have this here */

waitlost = ' '
waitlost_LO_hold = ' '
PW_loop_count = 0
do forever
nput='C-Ya! Then,Escape twice,First and Last name:,Password:,password to use:,for verification:,continue,mail now? [Y/n]:,3 Posted by,quit):,NO CARRIER'
wait nput
NRC = RC
NRESULT = RESULT
   if NRC > 0 then do  /* waited 30 seconds & no nput items on serial port */
      waitlost = 'y'
      msg '****** LOGON - wait is LOST! ******'
   end
   if NRESULT = 'Escape twice' then              /* A */
      send '\x1B\x1B'
   if NRESULT = 'First and Last name:' then      /* B */
      send 'Your Name\r'
   if NRESULT = 'Password:' then do              /* C C1 C2 */
      PW_loop_count = PW_loop_count + 1
      if PW_loop_count = 1 then
         send PW1'\r'                            /* C C1 */
      if PW_loop_count = 2 then do
         if exists('DH1:-dl/FAAX_PW2_used')=0 then do
            address command 'makedir DH1:-dl/FAAX_PW2_used'
         end
         send PW2'\r'                            /* C2 */
      end
      if PW_loop_count > 2 then do
         waitlost = 'y'
         msg '****** Logon PW_loop_count > 2 ******'
      end
   end
   if NRESULT = 'password to use:' then          /* S */
      send PW2'\r'
   if NRESULT = 'for verification:' then         /* T */
      send PW2'\r'
   if NRESULT = 'Press enter...' then            /* D */
      send '\r'
   if NRESULT = 'continue' then                  /* E F */
      send '\r'
   if NRESULT = 'mail now? [Y/n]:' then do       /* G */
      if auto = 'y' then do
         send 'y\r'
         waitlost_LO_hold = waitlost
         call MAIL_CALL
         if waitlost = 'n' then do
            waitlost = waitlost_LO_hold
            if exists('DH1:-dl/FAAX_MAIL_captured')=0 then do
               address command 'makedir DH1:-dl/FAAX_MAIL_captured'
            end
         end
      end
      else do
         if exists('DH1:-dl/FAAX_MAIL_waiting')=0 then do
            address command 'makedir DH1:-dl/FAAX_MAIL_waiting'
         end
         send 'n\r'
      end
   end
   if NRESULT = '3 Posted by' then do            /* Q R */
         if exists('DH1:-dl/FAAX_AlphaNews_captured')=0 then do
            address command 'makedir DH1:-dl/FAAX_AlphaNews_captured'
         end
         send '\w\r'
   end
   if NRESULT = 'quit):' then do                 /* U */
      waitlost = 'n'
      send '\r'
   end
   if NRESULT = 'C-Ya! Then' then                /* AM */
      waitlost = 'X'
   if NRESULT = 'NO CARRIER' then                /* if logon really gets  */
      waitlost = 'y'                             /*          LOST         */
                                                 /* this will get you OUT */
   if waitlost ~= ' ' then
      leave
end
return

MAIL_CALL:
address BAUD /* must have this here */

waitlost = ' '
do forever
nput='More(Y/n/=),(E)nter? (S)top:,(F)iles? (S)top:,to continue:,(Enter to continue):,(A)bort:,here [y/N],End of messages'

/* note use of ? to allow entry of a comma into nput above "(E)nter? (S)top:" */

wait nput
NRC = RC
NRESULT = RESULT
   if NRC > 0 then do /* waited 30 seconds & no nput items on serial port */
      waitlost = 'y'
      msg '****** MAIL_CALL - wait is LOST! ******'
   end
   if NRESULT = 'More(Y/n/=)' then               /* ? */
      send '='
   if NRESULT = '(E)nter, (S)top:' then          /* H N O */
      send 'n\r'
   if NRESULT = '(F)iles, (S)top:' then          /* I */
      send 'f\r'
   if NRESULT = 'to continue:' then              /* J */
      send '\r'
   if NRESULT = '(Enter to continue):' then      /* K */
      send '\r'
   if NRESULT = '(A)bort:' then                  /* L */
      send 's\r'
   if NRESULT = 'here [y/N]' then                /* M */
      send 'y\r'
   if NRESULT = 'End of messages' then           /* P */
      waitlost = 'n'
   if waitlost ~= ' ' then
      leave
end
return


AUTO_NEW_FILE_LIST:
address BAUD /* must have this here */

waitlost = ' '
TL_loop_count = 0
do forever
nput='Command ->,Enter Disk Number:,Time Left [,Search Date,Previous Page:'
wait nput
NRC = RC
NRESULT = RESULT
   if NRC > 0 then do  /* waited 30 seconds & no nput items on serial port */
      waitlost = 'y'
      msg '****** AUTO_NEW_FILE_LIST - wait is LOST! ******'
   end
   if NRESULT = 'Command ->' then                /* T */
      send 't\r'
   if NRESULT = 'Enter Disk Number:' then        /* W */
      send '0\r'
   if NRESULT = 'Time Left [' then do            /* X Y */
      TL_loop_count = TL_loop_count + 1
      if TL_loop_count = 1 then
         send '#'                                /* X */
      if TL_loop_count = 2 then
         send 'n'                                /* Y */
      if TL_loop_count = 3 then do
         waitlost = 'n'
         send 'q'                                /* AB */
      end
      if TL_loop_count > 3 then do
         waitlost = 'y'
         msg '****** Auto_New_File_List TL_loop_count > 3 ******'
      end
   end
   if NRESULT = 'Search Date' then               /* Z */
      send '\r'
   if NRESULT = 'Previous Page:' then            /* AA */
      send 'y'
   if waitlost ~= ' ' then
      leave
end
return


AUTO_FILE_DL:
OPTIONS RESULTS
address command

address BAUD /* must have this here */

call open('FL','dh1:-dl/DL_FAAX','R')
FLN = readln('FL')
upper FLN
call close('FL')
waitlost = ' '
DL_loop_count = 0
do forever
nput='Command ->,Enter Disk Number:,Time Left [,Select Protocol:,Choice:,To Download:,Hangup After Transfer?,h To Hangup Now:'
wait nput
NRC = RC
NRESULT = RESULT
   if NRC > 0 then do  /* waited 30 seconds & no nput items on serial port */
      waitlost = 'y'
      msg '****** AUTO_FILE_DL - wait is LOST! ******'
   end
   if NRESULT = 'Command ->' then                /* AC */
      send 't\r'
   if NRESULT = 'Enter Disk Number:' then        /* ? */
      send '0\r'
   if NRESULT = 'Time Left [' then do            /* AD AE ? */
      DL_loop_count = DL_loop_count + 1
      if DL_loop_count = 1 then                  /* AD */
         send '#'
      if DL_loop_count = 2 then
         send 'd'                                /* AE */
      if DL_loop_count = 3 then do
         waitlost = 'n'
         send 'Q'                                /* AJ */
      end
      if DL_loop_count > 3 then do
         waitlost = 'y'
         msg '****** AUTO_FILE_DL - DL_loop_count > 3 ******'
      end
   end
   if NRESULT = 'Select Protocol:' then          /* AF */
      send 'Z'
   if NRESULT = 'Choice:' then                   /* AG */
      send 'G'
   if NRESULT = 'To Download:' then              /* AH */
      send FLN'\r'
   if NRESULT = 'Hangup After Transfer?' then    /* AI */
      send 'N'
   if waitlost ~= ' ' then
      leave
end

return


LOGOFF:
address BAUD /* must have this here */

waitlost = ' '
CMD_loop_count = 0
do forever
nput='Command ->'
wait nput
NRC = RC
NRESULT = RESULT
   if NRC > 0 then do  /* waited 30 seconds & no nput items on serial port */
      waitlost = 'y'
      msg '****** Logoff wait is LOST! ******'
   end
   if NRESULT = 'Command ->' then do             /* AK AL */
      CMD_loop_count = CMD_loop_count + 1
      if CMD_loop_count = 1 then
         send 'g\r'                              /* AK */
      if CMD_loop_count = 2 then do
         waitlost = 'n'
         send 'y\r'                              /* AL */
      end
      if CMD_loop_count > 2 then do
         waitlost = 'y'
         msg '****** LOGOFF - CMD_loop_count > 2 ******'
      end
   end
   if waitlost ~= ' ' then
      leave
end
return